How can I check a radio button after multiple are programmatically created? Topic is solved

[IMTheNachoMan]

I am programatically creating multiple radio buttons like so:

Code: Select all

radioName := " VmyDetails"
for k, v in obj
{
   myGUI.add("Radio", radioName, k)
   radioName := ""
}

I know I can get the selected radio button like so:

Code: Select all

selectedRadioIndex := myGUI.Submit(False).myDetails

But, before I show the GUI, I want to find a radio button by it's index and check it. How can I do that?

I can't check the radio buttons while they are being created. The GUI will be shown/hidden numerous times and each time a different radio button should be selected.

[teadrinker]

I'm not sure I got what you were trying to accomplish, but probably something like this:

Code: Select all

wnd := Gui()
for k, v in ['one', 'two', 'three', 'four', 'fife'] {
    wnd.AddRadio(k = 1 ? 'VmyDetails' : '', v)
}
; check 3rd radio
firstRadioClassNN := ControlGetClassNN(wnd['myDetails'])
firstRadioNumber := SubStr(firstRadioClassNN, 7)
wnd['Button' . (firstRadioNumber + 2)].Value := 1
wnd.Show()

[just me]

Another option:

Code: Select all

#Requires AutoHotkey 2.0
#Warn
RadioButtons := ["One", "Two", "Three", "Four", "Five"]
Wnd := Gui()
Wnd.OnEvent("Close", (*) => ExitApp())
RadioGroup := []
For K, V In RadioButtons {
   RadioGroup.Push(Wnd.AddRadio("xm w300", V))
}
; check 3rd radio
RadioGroup[3].Value := 1
Wnd.AddButton("xm w300", "Get checked").OnEvent("Click", GetCheckedRadio)
Wnd.Show()

GetCheckedRadio(*) {
   Local CheckedRadio := 0
   For I, RadioCtrl In RadioGroup
      CheckedRadio := RadioCtrl.Value ? I : 0
   Until CheckedRadio
   MsgBox(CheckedRadio)
}

[IMTheNachoMan]

Thank you both @teadrinker and @just me!

[songdg]

@just me
How to make the RadioGroup horizontal?

[IMTheNachoMan]

@songdg You can do that with the x/y placement options of gui.add.

https://www.autohotkey.com/docs/v2/lib/Gui.htm#Add

[songdg]

@IMTheNachoMan
Thank you very much.