How can I dynamically create hotkeys with HotKey that calls a function with additional paramaters? Topic is solved

[IMTheNachoMan]

Below is a basic example of what I am trying to do.

I commented out the 3 lines because none of them work.

I am dynamically creating hotkeys from config data using HotKey. The hotkey will call a function. When the hotkey is triggered, I want additional data to be sent to the function.

Code: Select all

#Requires AutoHotkey v2.0
#Warn Unreachable, off
#SingleInstance Force

data := ["^!+a", "^!+b", "^!+c"]

for i, v in data
{
    ; HotKey v, (ThisHotKey) => dingo(i, v)
    ; HotKey v, (ThisHotKey) => dingo.bind(i, v)
    ; HotKey v, dingo.bind(i, v)
}

dingo(index, data)
{
    msgbox index " " data
    return
}

[boiler]

If Action is a function, it is called with one parameter, the name of the hotkey.

[boiler]

This achieves the same result:

Code: Select all

#Requires AutoHotkey v2.0
#Warn Unreachable, off
#SingleInstance Force

data := ["^!+a", "^!+b", "^!+c"]

for i, v in data
    HotKey v, dingo

dingo(thisHotkey) {
	for i, v in data
		if (v = thisHotkey)
			index := i
    MsgBox index " " thisHotkey
}

[IMTheNachoMan]

If Action is a function, it is called with one parameter, the name of the hotkey.

Yes, I saw that. So I'm trying to figure out how to call the function with additional data.

[IMTheNachoMan]

This achieves the same result:

Code: Select all

#Requires AutoHotkey v2.0
#Warn Unreachable, off
#SingleInstance Force

data := ["^!+a", "^!+b", "^!+c"]

for i, v in data
    HotKey v, dingo

dingo(thisHotkey) {
	for i, v in data
		if (v = thisHotkey)
			index := i
    MsgBox index " " thisHotkey
}

So I thought that too. But there must be some more efficient way? It would be very slow to have to loop through the data every time a hotkey is pressed.

There must be some mechanism to pass data to a hotkey function?

[boiler]

But there must be some more efficient way? It would be very slow to have to loop through the data every time a hotkey is pressed.

Code: Select all

#Requires AutoHotkey v2.0
#Warn Unreachable, off
#SingleInstance Force

data := Map("^!+a", 1, "^!+b", 2, "^!+c", 3)

for i, v in data
    HotKey i, dingo

dingo(thisHotkey) {
    MsgBox data[thisHotkey] " " thisHotkey
}

[IMTheNachoMan]

@boiler

Hurmph. That is what I am currently doing. I guess it works. I just thought maybe there would be a better way...

[ntepa]

Code: Select all

#Requires AutoHotkey v2.0
#Warn Unreachable, off
#SingleInstance Force

data := ["^!+a", "^!+b", "^!+c"]

for i, v in data
{
	Hotkey v, dingo.Bind(i, v)
}

dingo(index, data, *) ; * allows extra parameters to be ignored
{
    msgbox index " " data
    return
}

[IMTheNachoMan]

@ntepa

Ah. So the , * is needed in the bind. I didn't know that.

Do you mind explaining why? I get that bind returns a BoundFunc with "pre defined parameters". So why is the , * needed?

[boiler]

It's because he bound two additional parameters in addition to the default parameter that I posted about. As his comment in his script points out, the * tells it to ignore any additional parameters sent. Notice that you can actually have it accept that parameter instead of ignoring it:

Code: Select all

#Requires AutoHotkey v2.0
#Warn Unreachable, off
#SingleInstance Force

data := ["^!+a", "^!+b", "^!+c"]

for i, v in data
{
	Hotkey v, dingo.Bind(i, v)
}

dingo(index, data, thisHotkey)
{
    msgbox index " " data " " thisHotkey
    return
}

[IMTheNachoMan]

@boiler

It appears that when you use bind with hotkey, the called function has additional parameters then what you bound. I didn't know/realize that. I now see it sends an additional parameter of the hotkey.

[boiler]

It sends the default one in addition to the newly bound ones. Binding new parameters doesn't remove the parameter that is already associated with a hotkey function.

[IMTheNachoMan]

@boiler Yeah, I see that now. I missed this part of the documentation from https://www.autohotkey.com/docs/v1/misc/Functor.htm#BoundFunc:

When the BoundFunc is called, it calls the function or method to which it is bound, passing any bound parameters followed by any which were passed by the caller.