Different output depends on how long to hold a key Topic is solved

[akirofe]

Hi awesome people ,

Could you please kindly help me?

Could you please help me with a codes (or if you don't have time, a link for what to read specifically to do this:) so that:

For a key (say, F3):

1. While being pressed, it will stop mouse movement (so I can re-position my mouse without have to lift it up the mouse mat). And If I press another key while being pressed, it will do something else, say writing my email address automatically.
2. If I release quickly like a normal keypress action (without pressing any other key), it will send "Enter".
(3. And when I release, it will of course resume normal mouse movement.)

Thank you very much! <3

[WarlordAkamu67]

@akirofe This will make F3 send Enter on a press, and block mouse movement on a hold. While holding F3, the keys "a", "b", and "c" can be used to display a MsgBox- alter to your liking.

Code: Select all

#Requires AutoHotkey v2.0

key_is_Held := 0

; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;
; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;
; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;

multiKey() {
  if (GetKeyState("F3", "P")) {
    BlockInput("MouseMove")
    global key_is_Held := 1
    while (GetKeyState("F3", "P")) {
      Sleep(100)
}
    global key_is_Held := 0
    BlockInput("MouseMoveOff")
} else {
    Send("{Enter}")
}
  return
}

; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;
; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;
; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;

F3:: {
  SetTimer(multiKey, -200)
  KeyWait("F3")
  return
}

; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ; ------------------------- ;

#HotIf (key_is_Held)
a:: {
  MsgBox("Extra Function on F3 + a")
  return
}

b:: {
  MsgBox("Extra Function on F3 + b")
  return
}

c:: {
  MsgBox("Extra Function on F3 + c")
  return
}

[akirofe]

Wow... Thank you very much WarlordAkamu67 !!! I'll apply and will report back!!! Have a wonderful day WarlordAkamu67 !!

[akirofe]

IT WORKS B.E.A.U.T.I.F.U.L.L.Y dear WarlordAkamu67 !!! I am sooooo happy and grateful!!! How can I buy you beers please PM me

[WarlordAkamu67]

@akirofe
Thank you for the offer, cheers.

I am glad to hear it worked out ^.^ ... It is most helpful for topics with solutions to be marked as solved/resolved.

[teadrinker]

You can make it a little easier:

Code: Select all

F3:: {
    BlockInput('MouseMove'),
    KeyWait('F3', 'T.3') && Send('{Enter}')
    KeyWait 'F3'
    BlockInput 'MouseMoveOff'
}