Maps keys in a DD-list, how? Topic is solved

[Krd]

Hallo everyone

I have this:

Code: Select all

F12::function_name()

function_name()
{
    Test(&Test2)
    MyGui := Gui()
    MyGui.Add("DropDownList", "vSelectedKey", ['First','Second'])
    MyGui.Add("Button", , "Submit").OnEvent("Click", Submit)
    MyGui.Show()

Submit(*)
{
Saved := MyGui.Submit(true)
MsgBox Test2[Saved.SelectedKey]
}
}



Test(&Test2)
{
Test2 := Map(
'First', 'First value',
'Second', 'Second value',
)
}

And this becomes a problem when my maps have hundreds of keys, making it difficult to manage and update the GUI efficiently.

Code: Select all

   MyGui.Add("DropDownList", "vSelectedKey", ['First','Second'])

And then I don't want to duplicate every key if I do this:

Code: Select all

Test_only_keys(&Test3)
{
Test3 :=
[
'First', 
'Second'
]
}

And is it possible to dynamically retrieve the keys and display them in the dropdown list, along with showing the corresponding value upon submission, like a pro?

The dropdownlist would only show the existing keys in the map.

[mikeyww]

Hello,

You can assign your DDL object to a variable and then use the Add and Delete methods to change the values.

Read: https://www.autohotkey.com/docs/v2/lib/GuiControl.htm#Add

[just me]

Code: Select all

F12::SelectKey("TestKeys")
F11::SelectKey("OtherKeys")

SelectKey(KeyFuncName) {
   KeyMap := %KeyFuncName%()
   KeyArr := []
   For Key In KeyMap
      KeyArr.Push(Key)
   MyGui := Gui()
   MyGui.OnEvent("Close", (*) => MyGui.Destroy())
   MyGui.Add("DropDownList", "vSelectedKey Choose1", KeyArr)
   MyGui.Add("Button", , "Submit").OnEvent("Click", Submit)
   MyGui.Show()
   WinWaitClose(MyGui.Hwnd)
   Submit(*) {
      Saved := MyGui.Submit()
      MsgBox KeyMap[Saved.SelectedKey]
      MyGui.Destroy()
   }
}

TestKeys() {
   Return Map('First', 'First value',
              'Second', 'Second value')
}
OtherKeys() {
   Return Map('Third', 'Third value',
              'Fourth', 'Fourth value')
}

?

[Krd]

Thank you both! Sorry for bad explanation again from me, mikey, I see that I did a bad job there.

"just me" that's exactly what I wanted, a for loop does that! I just didn't know how to do it.

This way I do not have to duplicate keys for a map and maintain two maps that work for the same goal.
This makes it more error free and easier to edit.

Much appreciated!