More efficient coding?

[CuriousDad]

Hi. I'm trying to figure out if there is a more efficient way to inserting a delay after every command. The delay seems to help with the accuracy of the keystroke. The delay functions such as SetKeyDelay or SetControlDelay don't seem to be what I'm looking for.

Current Code to sort items in a folder by type:

Code: Select all

Send {F10}
Sleep 250
Send {Right}
Sleep 250
Send {Enter}
Sleep 250
Send {Down 6}
Sleep 250
Send {Right}
Sleep 250
Send {Down 2}
Sleep 250
Send {Enter}
return

Any thoughts? Thanks.

[RussF]

Is this your entire script? SetKeyDelay should work since V1 uses SendEvent mode by default. If, however, you have used SendMode Input (inserted automatically if you create a new ahk file with the built-in template), then SetKeyDelay has no effect. Also, 250ms between keys seems like an awful long time just to move a cursor around.

Russ

[CuriousDad]

Thanks. In reading the documentation, I thought that SetKeyDelay created delays between keystrokes (such as typing out a word) and how long a key is held down. If so, does it really space out each command function? I placed 250 ms between each command because sometimes, the commands moves faster than cursor and steps get missed.

[Rohwedder]

Hallo,
or with a Timer?:

Code: Select all

q:: ;start/restart
Sends := ["F10","Right","Enter","Down 6","Down 2","Enter"]
Count := 0
Sends:
Send,% "{" Sends[++Count] "}"
SetTimer, Sends,% Count-Sends.Count()?250:"Off" ;every 250 ms
Return

or:

Code: Select all

q:: ;start/restart
Sends := ["F10","Right","Enter","Down 6","Down 2","Enter"]
Sleeps := [250,250,250,250,250,"Off"], Count := 0
Sends:
Send,% "{" Sends[++Count] "}"
SetTimer, Sends,% Sleeps[Count]
Return

[boiler]

Thanks. In reading the documentation, I thought that SetKeyDelay created delays between keystrokes (such as typing out a word) and how long a key is held down. If so, does it really space out each command function? I placed 250 ms between each command because sometimes, the commands moves faster than cursor and steps get missed.

To use this approach and ensure correct settings as pointed out by RussF:

Code: Select all

SetKeyDelay, 250
SendEvent, {F10}{Right}{Enter}{Down 6}{Right}{Down 2}{Enter}
SetKeyDelay, 10 ; set back to default if there is more to the script

By using SendEvent instead of Send, it doesn’t matter if you have set SendMode to Input at the top of the script. That only applies when using Send specifically.

[Rohwedder]

But SetKeyDelay has a side effect!
https://www.autohotkey.com/docs/v1/lib/SetKeyDelay.htm#Remarks
During the delay (sleep), the current thread is made uninterruptible.
Try to trigger with s:: SoundBeeps while the q:: hotkey routine is sending (does not work).
While the w:: hotkey routine is sending this works (and with my timer anyway!).

Code: Select all

s::SoundBeep, 4000, 20
q::
SetKeyDelay, 250
SendEvent, {F10}{Right}{Enter}{Down 6}{Right}{Down 2}{Enter}
SetKeyDelay, 10 ; set back to default if there is more to the script
Return
w::
Send {F10}
Sleep 250
Send {Right}
Sleep 250
Send {Enter}
Sleep 250
Send {Down 6}
Sleep 250
Send {Right}
Sleep 250
Send {Down 2}
Sleep 250
Send {Enter}
return

[CuriousDad]

Thanks to everyone for the response. I'll try it out.

Update: Success! Thank you!