Open a pdf file in Chrome New tab

[w_i_k_i_d]

Hello

Trying to :-

1. Select a file (with mouse)
2. Press a key (RAlt + l)
3. Open it in already open chrome and in a new tab.

So I have : (from google searches etc)

Code: Select all

>!l::  			;;  RAlt + L
{
    Var := % Explorer_GetSelection()                
	Run "C:\Program Files\Google\Chrome\Application\chrome.exe /newtab" %Var%
Return
}

Thanks


[Mod edit: Added [code][/code] tags. Please use them yourself when posting code.]

[Mod action: Topic moved from "Ask for Help (v2)" since this is v1 code.]
[Mod action: Moved topic back to v2 help since this seems to be a translation request.]

[V0RT3X]

I would lose the brackets...

Code: Select all

>!l::  			;;  RAlt + L
    Var := % Explorer_GetSelection()                
	Run "C:\Program Files\Google\Chrome\Application\chrome.exe /newtab" %Var%
Return

You will also need the Explorer_GetSelection() function for this if you don't already have it. Looks to be a version of this old script possibly?
https://www.autohotkey.com/board/topic/100983-how-can-we-retrieve-the-name-of-a-file-selected/

[w_i_k_i_d]

I was pretty sure I posted this in AHK 2.0 section

[Mod action: Topic moved from "Ask for Help (v2)" since this is v1 code.]

Can I please get this script for AHK 2.0
Thanks

[gregster]

I was pretty sure I posted this in AHK 2.0 section

[Mod action: Topic moved from "Ask for Help (v2)" since this is v1 code.]

Can I please get this script for AHK 2.0

I moved the topic back to v2 help.
Generally, if you post v1 code and want it translated to v2, it would be good to state this in the original post since most people - and especially new forum users - who post v1 code in the v2 help subforum are doing that erroneously.

[mikeyww]

Code: Select all

; This script opens selected files in the Chrome Web browser
#Requires AutoHotkey v2.0

#HotIf WinActive('ahk_class CabinetWClass') && WinExist('ahk_exe chrome.exe')
>!l:: {
 SoundBeep 1500
 For item in Explorer_GetSelection() {
  Run 'chrome.exe ' item
  Sleep 500
 }
}
#HotIf

Explorer_GetSelection() {
 ; Adapted: https://www.autohotkey.com/boards/viewtopic.php?style=17&t=60403#p255256 by teadrinker
 ; https://www.autohotkey.com/boards/viewtopic.php?p=509080#p509080
 hwnd := WinExist('A'), selection := []
 If WinGetClass() ~= '(Cabinet|Explore)WClass'
  For window in ComObject('Shell.Application').Windows {
   Try window.hwnd
   Catch
    Return
   If window.hwnd = hwnd
    For item in window.document.SelectedItems
     selection.Push(item.Path)
  }
 Return selection
}

[w_i_k_i_d]

Thanks Mikeyww

Giving this a try
I heard the beep, which is amazing to hear

System can't find Chrome.exe
replaces that with "C:\Program Files\Google\Chrome\Application\chrome.exe"
still can't find it

[w_i_k_i_d]

Changed it back to Mikeyww's script 'chrome.exe'
and somehow I don't get that error anymore from AHK reload but
instead a small popup window opened like the one for Open With saying:-

"You will need a new app to open chrome.exec" (notice the 'c' at the end)
'Look for an app in Microsoft store'
'Always use this app'

And I'm pretty sure Chrome is not in Microsoft app store.

(please see attached screenshots)

Also I would like to learn this language Mikeyww
Is it C## Cbash ?

[boiler]

Notice the difference between the two MsgBox displays and why, and look at the difference between mikeyww's code and what the error message shows for your code.

Code: Select all

#Requires AutoHotkey v2.0
item := 'c'
MsgBox 'chrome.exe' item
MsgBox 'chrome.exe ' item

[w_i_k_i_d]

That space did wonders
It works ! Its alive !
Thank you so much