Selecting items randoms from a list

[PuzzledGreatly]

What's the most efficient method to select a given number of items randomly from a list so that no item is selected more than once. I'm currently using the following:

Code: Select all

	
Total = 30 ;for example
nUp = 6 ; for example select 6 items
t = 1
	While t <= nUP
	{		
		Retry:
		Random, Ran, 1, %Total%
		if Ran <> TargN
		if Ran not in %numbers%
		numbers = %numbers%%Ran%,
		else
		goto Retry
		t ++		
	}
msgbox %numbers%

But I think there must be a better way.

[tmplinshi]

Just a shorter one:

Code: Select all

Total := 30 ; for example
nUp   := 6  ; for example select 6 items
t     := 1

While t <= nUP
{
	Random, Ran, 1, %Total%
	if Ran not in %numbers%
		numbers .= Ran ",", t ++
}

MsgBox %numbers%

[Verdlin]

t isn't even necessary. A_Index works fine

Code: Select all

Total := 30 ; for example
nUp   := 6  ; for example select 6 items

While (A_Index <= nUP)
{
    Random, Ran, 1, %Total%
    if Ran not in %numbers%
        numbers .= Ran ",", (A_Index) ; A_Index is faster when forced to an expression, i.e. (A_Index)
}

MsgBox %numbers%

[LinearSpoon]

It is necessary actually. A_Index still increments even if the random number chosen was picked in a prior loop iteration. It could be removed with a second loop I suppose...but that's probably more work than it saves.

Also, since you have a comma on that line... your entire expression is just this:

Code: Select all

(A_Index)

...which doesn't really do anything to begin with.

[PuzzledGreatly]

Thanks, tmplinshi, that's much neater than my original method.

[kon]

Code: Select all

#NoEnv
SetBatchLines, -1
Total := 300000
nUp   := 60000
t     := 1
n     := {}


Tick := A_TickCount
While t <= nUP
{
    Random, Ran, 1, %Total%
    if (!n[Ran])
        n[Ran] := 1, t++, numbers .= Ran ","
}
MsgBox, % A_TickCount - Tick "ms.`n" numbers


t     := 1
numbers := ""
Tick := A_TickCount
While t <= nUP
{
    Random, Ran, 1, %Total%
    if Ran not in %numbers%
        numbers .= Ran ",", t ++
}
MsgBox, % A_TickCount - Tick "ms.`n" numbers

[empardopo]

t isn't even necessary. A_Index works fine

Code: Select all

Total := 30 ; for example
nUp   := 6  ; for example select 6 items

While (A_Index <= nUP)
{
    Random, Ran, 1, %Total%
    if Ran not in %numbers%
        numbers .= Ran ",", (A_Index) ; A_Index is faster when forced to an expression, i.e. (A_Index)
}

MsgBox %numbers%

Using this code, I get this



Is this correct? I only get five numbers. Other times I got four.

However, running this code

Code: Select all

Total := 30 ; for example
nUp   := 6  ; for example select 6 items
t     := 1

While t <= nUP
{
    Random, Ran, 1, %Total%
    if Ran not in %numbers%
        numbers .= Ran ",", t ++
}

MsgBox %numbers%

I always get six numbers.

Greetings!

[dmg]

One reliable and relatively efficient way to randomly shuffle a list with no repeats is to use the Fisher-Yates Shuffle:

Code: Select all

msgbox, % _shuffle("abcdefghijklmnopqrstuvwxyz")
msgbox, % _shuffle("one two buckle my shoe", " ")
msgbox, % _shuffle("three|four|close|the|door", "|")

_shuffle(input, delimiter = "")
 {
   delimiter := (!instr(input, substr(delimiter, 1, 1)) ? "" : substr(delimiter, 1, 1))
   array := {}
   loop, parse, input, %delimiter%
    {
      array.insert(a_loopfield)
    }
   while, array.maxindex()
    {
      random, ran, 1, array.maxindex()
      shuffled .= delimiter . array[ran]
      array.remove(ran)
    }
   return ltrim(shuffled, delimiter)
 }

You could also just use the random parameter of the Sort command.
http://en.wikipedia.org/wiki/Fisher%E2% ... es_shuffle

[empardopo]

Is It possible to get only 3 elements using _shuffle function?

msgbox, % _shuffle("abcdefghijklmnopqrstuvwxyz",3)

And get for example, a m and z...

Greetings!

[sinkfaze]

For the OP:

Code: Select all

total := 30, nUp := 6
 , n := numbers :=	""
Loop
	n .=	A_Index ","
Until	(A_Index=total)
Total :=	SubStr(Total,1,StrLen(Total)-1)
Sort, n, Random D`,
Loop, parse, n, `,
	numbers .=	A_LoopField ","
Until	(A_Index=nUp)
numbers :=	SubStr(numbers,1,StrLen(numbers)-1)
MsgBox %numbers%

[PuzzledGreatly]

Thanks for the replies. Now I'm wondering what the best method is to pull one or more chosen items with a given number of random items.

[AfterLemon]

Accepted Inputs:
Var Containing Comma-Delimited Strings
Array*
Max Number

To output an amount of random numbers using 1-%Max% (inclusive) use:
Msgbox,% RandItems(10,,30)

To output array with an amount of randomized elements from another array use something like:
Arr:=["blah","ahh","har","arrh","barr","bahh","rabb","arbb","harb","brah","rabh","arrh","arrr","rahh","raaa","baaa","haaa"]

Msgbox,% st_Printarr(RandItems(10,,Arr*))

To output string with an amount of random elements from another array use:
MsgBox,% (RandItems(10,1,Arr*)

Code: Select all

	
RandItems(NumOut,StringOut:=0,ArrOrMaxNum*){
	t:=1,O:=[]
	If((ArrOrMaxNum[1]&1!="")&&!(ArrOrMaxNum.MaxIndex()>1)){
		While(ArrOrMaxNum[1]--?1:(0,n:=SubStr(n,1,-1)))
			n.=A_Index	","
	}else If(ArrOrMaxNum.MaxIndex()>1){
		I:=ArrOrMaxNum.MaxIndex()
		While(I--?1:(0,n:=SubStr(n,1,-1)))
			n.=ArrOrMaxNum[A_Index] ","
	}else n:=ArrOrMaxNum[1]
	Sort,n,Random D`,
	Loop,parse,n,`,
		(StringOut?O.=A_LoopField	",":O[t].=A_LoopField),t++
	Until T=NumOut+1
return (O.HasKey(O.MaxIndex())?O:RTrim(O,","))
}
;==============================
st_printArr(array, depth:=5, indentLevel:="")
{
	for k,v in Array
		list.=indentLevel "[" k "]",((IsObject(v)&&depth>1)?(list.="`n" st_printArr(v,depth-1,indentLevel " 	")):list.=" => " v),list.="`n"
	return rtrim(list)
}

Note: st_PrintArr function is ONLY used to show contents of the output array.

[FanaticGuru]

If you are truly wanting a number of random items from a list and not just non-repeating random numbers you can do this:

Code: Select all

List = 
(Join`n
apple
banana
grape
pear
pineapple
)

X := 3

Sort, List, Random

MsgBox % SubStr(List,1,InStr(List,"`n",1,1,x))

FG