ComObject("HTMLfile") for extracting HTML Source from clipboard Topic is solved

[JoeSchmoe]

Thanks! Seemed to work fine beforehand anyway due to the null termination.

[FanaticGuru]

Yep, in AHK v1 StrPut() returns the size in characters, not bytes, hence the confusion.

That is really good to know. I pondered for quite a bit if it was supposed to be "* 2" or "* 2 + 8".

I am still learning and not confident on getting everything just right with DllCall, StrPut, offsets, buffers, etc. In the future that will be one less thing to worry about.

FG

[teadrinker]

I am still learning

Anyone who is involved in programming "is still learning".

[jkeks]

@chatGPT

Don't use chatGPT for AHK, it doesn't make sense. Perhaps you need this:

Code: Select all

F11:: {
    if CopySelectedText() {
        if html := ExtractHtmlData()
            url := RegExReplace(html, 's)(?<=href=")[^"]+(*SKIP)(*F)|.')
        MsgBox 'text: ' . A_Clipboard . '`nurl: ' . url
    }

    CopySelectedText() {
        ClipSaved := ClipboardAll()
        A_Clipboard := ''
        Send '^c'
        ClipWait 1
        if (A_Clipboard = '') {
            A_Clipboard := ClipSaved
            MsgBox 'Failed to copy data'
            return
        }
        return true
    }

    ExtractHtmlData() {
        static CF_HTML := DllCall('RegisterClipboardFormat', 'Str', 'HTML Format')
        DllCall('OpenClipboard', 'Ptr', A_ScriptHwnd)
        format := 0
        Loop {
            format := DllCall('EnumClipboardFormats', 'UInt', format)
        } until format = CF_HTML || format = 0
        if format != CF_HTML {
            DllCall('CloseClipboard')
            return
        }
        hData := DllCall('GetClipboardData', 'UInt', CF_HTML, 'Ptr')
        pData := DllCall('GlobalLock', 'Ptr', hData, 'Ptr')
        html := StrGet(pData, 'UTF-8')
        DllCall('GlobalUnlock', 'Ptr', hData)
        DllCall('CloseClipboard')
        return html
    }
}

Thank you for ExtractHtmlData() function )))