how to create nesting object Topic is solved

[cgx5871]

v1 code:

Code: Select all

a:={}
a["b","c","d","e"]:=3
MsgBox % a.b.c.d.e

v2 how to create this?

[mikeyww]

There may be better ways.

Code: Select all

#Requires AutoHotkey v2.0
a := {}
a.b := {}
a.b.c := {}
a.b.c.d := {}
a.b.c.d.e := 3
MsgBox a.b.c.d.e

I think I saw a script a while back that was written to make this easier or more straightforward.

AHK v2 uses expressions.

[FanaticGuru]

v1 code:

Code: Select all

a:={}
a["b","c","d","e"]:=3
MsgBox % a.b.c.d.e

v2 how to create this?

In v2, you are mixing two things:
a:={} <-- this is object syntax
a["b","c","d","e"]:=3<-- this is map syntax (multi-dimensional map)
MsgBox % a.b.c.d.e <-- this is object syntax

If you want to use an object with properties, you can make that a little easier with this function as @mikeyww suggested so you don't have to predefine default objects:

Code: Select all

ObjectDefaultCreate()
ObjectDefaultCreate() => Object.Prototype.DefineProp('__Get', {Call: (this, Name, Params) => this.%Name% := {}})

a:={}
a.b.c.d.e := 3
Msgbox a.b.c.d.e

Multi-dimension maps are not natively supported in v2. If you want to do a multi-dimension map, this function will allow that:

Code: Select all

a := MapN()
a["b", "c", "d", "e"] := 3
MsgBox a["b", "c", "d", "e"]

; Helgef: An "n-dimensional" map.
class MapN extends map {
	static __new()
		=> this.prototype.class := this
	__item[k1, p*] {
		get => p.length	? super[k1][p*] : super[k1]
		set {
			if	p.length && (!super.has(k1) || !(super[k1] is this.class))
				super[k1] := (this.class)()
			( p.length ) ? super[k1][p*] := value : super[k1] := value
		}
	}
}

So you can do either pretty much like in v2 but you cannot easily mix a.b.c.d.e syntax with a["b", "c", "d", "e"] as these are two different type object syntaxes.

In v1 there was one generic object, in v2 there are 3 different types of objects primarily for data:

• Object (the base generic object which uses Properties, Methods, and Values)
• Array (an extension of base object that uses a numbered Index and Values)
• Map (an extension of base object that uses mapped pairs of string Keys and Values)

There are other object types like Gui but Object, Array, and Map are the three main ones used for data. I would look each of those up in the documents to see the difference. They each have specific syntax.

FG

[cgx5871]

"So you can do either pretty much like in v2 but you cannot easily mix a.b.c.d.e syntax with a["b", "c", "d", "e"] as these are two different type object syntaxes."
=========================================

so Pity
I always think this is the biggest charm of v1