AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

Post your working scripts, libraries and tools
Typical-User
Posts: 8
Joined: 15 Jun 2019, 06:38

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

17 Jan 2020, 13:03

Hi evilC

I need your help in my script.
Im using several scripts of this one, (with different names ofcourse) to help me in a game.
So far, i used my keyboards keys to run/pause the scripts, but due to the number of scripts, i need to stop using them in order for scripts to work.
The only solution was to buy an additional keypad, and the starting keys to be from that keypad.
According to readme, the command which sends proper key from keypad is the AHI.SendKeyEvent(keyboardId, GetKeySC("a"), 1)
I have modified the script (the original script ive found it on internet after some search. i just modified a bit according to my needs) with this command.
While i have no errors, the only working key is the F7. It seems the command which sends the proper key from key pad is not working. Please helppppp.

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
;#Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#Persistent ;Interception hotkeys do not stop AHK from exiting, so use this
#include Lib\AutoHotInterception.ahk
#SingleInstance, Force

#MaxThreadsPerHotkey 9900

global AHI := new AutoHotInterception()

keyboardId := AHI.GetKeyboardId(0x0E8F, 0x0041)

Return ;<-- forced end of autoexecute section


F7::
WinActivate, gamename  ahk_class triuiScreen

Return


AHI.SendKeyEvent(keyboardId, GetKeySC("71"), 1)
::


   ENDRun := !ENDRun

   If (!ENDRun)

            Return

   While (ENDRun)
 
 {
WinActivate,  ahk_class tooltips_class32

Sleep, 333

SetDefaultMouseSpeed, 8

WinActivate, gamename ahk_class triuiScreen

Sleep 30
SendEvent {Click 1213, 722, down}{click 1222, 906, up}
;Sleep 5000

Sleep, 7600

   }

   Return
[Mod edit: [code][/code] tags added]
User avatar
evilC
Posts: 4776
Joined: 27 Feb 2014, 12:30

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

17 Jan 2020, 16:29

Much WTF in that script.

Code: Select all

AHI.SendKeyEvent(keyboardId, GetKeySC("71"), 1)
::
GetKeySC("71") there is no such key as "71"
:: Why is there a double-colon here??

Even if the SendKeyEvent command did work, all the code would do is press and hold one key for ever, so no idea why you would want that
It looks like you are trying to use AHI to declare a hotkey, but the code is actually attempting to press a key that does not exist
Typical-User
Posts: 8
Joined: 15 Jun 2019, 06:38

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

17 Jan 2020, 16:49

AHI monitor gives code 71 when i press that button. the double colon execute the script when proper button is pressed. (at least that supposed to do)
User avatar
evilC
Posts: 4776
Joined: 27 Feb 2014, 12:30

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

17 Jan 2020, 16:52

Typical-User wrote:
17 Jan 2020, 16:49
AHI monitor gives code 71 when i press that button
Then you already have the key code and don't need to use GetKeySC() to find the code from the name
Typical-User wrote:
17 Jan 2020, 16:49
the double colon execute the script when proper button is pressed. (at least that supposed to do)
No, double colon syntax is specific to AHK hotkeys, you cannot use AHI commands with double colons
Even if you could, you are using the AHI syntax for SENDING a key, not declaring a hotkey to it

It's kind of like putting Send a:: in a script, which obviously won't work
You need to use one of the AHI Subscribe functions to subscribe to a key
Typical-User
Posts: 8
Joined: 15 Jun 2019, 06:38

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

18 Jan 2020, 04:49

Today i had some progress. From code in this thread (https www.reddit.com /r/AutoHotkey/comments/8s3vkr/autohotinterception_help_request/e101lmk/) Broken Link for safety
I managed to find out the command for the numpad's key, and add it to my script's code. Script is working. When i press the NumpadHome key, (hiding also that key from keyboard) it executes the script.
But now i have one serious problem. I started with 5 scripts, and now have ended with 10 !!!!!!! (one script which captures the proper key when pressed by keypad and starts the game's character key).
I tried to modify it, but first, when i press the F7 key (AHK command) loads the game client, but it stops there,
or if i disable the command of F7 key, it proceed to the rest of the script, but without having the control to pause it with same button. It just runs forever :(.
Is there any way to combine the two scripts? (the code of the new script below)
Thanks in Advance

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

#MaxThreadsPerHotkey 9900
#SingleInstance force
#Persistent
#include Lib\AutoHotInterception.ahk
AHI := new AutoHotInterception()
keyboardId := AHI.GetKeyboardId(0x0E8F, 0x0041)

F9::
WinActivate, gamename ahk_class triuiScreen
Return

; The "true" parameter in SubscribeKey tells AHI to BLOCK (Hide from the OS) this key.
AHI.SubscribeKey(keyboardId, GetKeySC("NumpadHome"), true, Func("KeyEvent"))
return

KeyEvent(state){
	global AHI, keyboardId
    ; state will be 1 on key press, 0 on key release
	if (!state)
		return    ; Ignore key release events
	AHI.SendKeyEvent(keyboardId, GetKeySC("Right"), 1)
	
ENDRun := !ENDRun

If (!ENDRun)
	
Return

While (ENDRun)
	
{
	WinActivate,  ahk_class tooltips_class32
	
	Sleep, 333
	
	SetDefaultMouseSpeed, 8
	
	WinActivate, gamename ahk_class triuiScreen
	Mousemove, 1245, 894, 0
	Sleep 30
	SendEvent {Click 1255, 904, down}{click 1185, 725, up}
	Sleep 30
	MouseMove, 1248, 988, 0
	
	Sleep, 5000
	
}

Return
}
[Mod edit: [code][/code] tags added]
User avatar
evilC
Posts: 4776
Joined: 27 Feb 2014, 12:30

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

18 Jan 2020, 06:26

Move the subscribe command to the auto-execute section

Code: Select all

AHI := new AutoHotInterception()
keyboardId := AHI.GetKeyboardId(0x0E8F, 0x0041)

; The "true" parameter in SubscribeKey tells AHI to BLOCK (Hide from the OS) this key.
AHI.SubscribeKey(keyboardId, GetKeySC("NumpadHome"), true, Func("KeyEvent"))
return

F7::
...
Typical-User
Posts: 8
Joined: 15 Jun 2019, 06:38

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

18 Jan 2020, 17:33

A correction. The previous script worked because the very first script was active (compiled in exe), and not because the second script was working.
i Moved the F7:: command to auto-execute section, but is not working as itended.
If i place a While after if (!state), script runs forever. If i remove While, it runs only once.It seems loop is not properly set up. I tried all day today to solve it, but with out any luck. Any help is appreciated.

Code: Select all

#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn ; Enable warnings to assist with detecting common errors.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.

#MaxThreadsPerHotkey 1
#SingleInstance force
#Persistent
#include Lib\AutoHotInterception.ahk
AHI := new AutoHotInterception()
keyboardId := AHI.GetKeyboardId(0x0E8F, 0x0041)


; The "true" parameter in SubscribeKey tells AHI to BLOCK (Hide from the OS) this key.
AHI.SubscribeKey(keyboardId, GetKeySC("NumpadHome"), true, Func("KeyEvent"))
return

F9::
WinActivate, gamename ahk_class triuiScreen
Return

KeyEvent(state)
{
	
	global AHI, keyboardId
; state will be 1 on key press, 0 on key release
	if (!state)
		return ; Ignore key release events
	
		WinActivate, ahk_class tooltips_class32
		
		Sleep, 333
		
		SetDefaultMouseSpeed, 8
		
		WinActivate, gamename ahk_class triuiScreen
		Mousemove, 1245, 894, 0
		Sleep 30
		SendEvent {Click 1255, 904, down}{click 1185, 725, up}
		Sleep 30
		MouseMove, 1248, 988, 0
		
		Sleep, 5000
	}
		
Return
User avatar
evilC
Posts: 4776
Joined: 27 Feb 2014, 12:30

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

20 Jan 2020, 06:24

Typical-User wrote:
18 Jan 2020, 17:33
i Moved the F7:: command to auto-execute section, but is not working as itended.
If i place a While after if (!state), script runs forever. If i remove While, it runs only once.It seems loop is not properly set up.
This is because you do not understand how threading works in AHK. Your first example used #MaxThreadsPerHotkey to allow a hotkey to fire even when it was already running, which allowed you to turn off the hotkey.
AHI does not support this, you need to code this mechanism properly and not use a bodge.

NEVER, EVER use a while loop in a hotkey to indefinitely repeat something. Use SetTimer instead

Code: Select all

#include Lib\AutoHotInterception.ahk
AHI := new AutoHotInterception()
keyboardId := AHI.GetKeyboardId(0x0E8F, 0x0041)
AHI.SubscribeKey(keyboardId, GetKeySC("NumpadHome"), true, Func("KeyEvent"))
return

KeyEvent(state){
	global ENDRun
	if (!state)
		return    ; Ignore key release events
	
	ENDRun:= !ENDRun
	if (ENDRun)
		SetTimer, DoRepeatingThing, Off
	else
		SetTimer, DoRepeatingThing, 5000 ; Fire DoRepeatingThing every 5 seconds
}

DoRepeatingThing:
	WinActivate,  ahk_class tooltips_class32
	
	Sleep, 333
	
	SetDefaultMouseSpeed, 8
	
	WinActivate, gamename ahk_class triuiScreen
	Mousemove, 1245, 894, 0
	Sleep 30
	SendEvent {Click 1255, 904, down}{click 1185, 725, up}
	Sleep 30
	MouseMove, 1248, 988, 0
	return
Typical-User
Posts: 8
Joined: 15 Jun 2019, 06:38

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

20 Jan 2020, 22:36

Youre right about that. Im not programmer. In some cases i can add some pieces of code in a script if is in very simple form.
Thank you for the code. Seems to work, but i managed to run with trouble only once yesterday. Today is not working at all.
Even the first pieces of code was warking so far, they not working anymore. Im pressing the buttons at keypad, but it does nothing.
Monitor captures the key presses in keypad, and displays the proper keys. It works even in text writer (notpad, notepad++ and such), but when i run the scripts, it does nothing. While running a cript, with double click on it, it brings forward a window which shows all the executed commands, but the mouse pointer is idle.
At first i thought was a problem with interception. But hardwareid and identify.exe works. Seems to be with AutohotInterception, but monitor, and information screen of the script, works too. I dont know what im missing. Any ideas?
turkeysh0t
Posts: 1
Joined: 23 Jan 2020, 08:56

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

23 Jan 2020, 09:06

Having some trouble getting AHI to work with my corsair k70 keyboard. Pretty odd as I can get it to work with an old cheap keyboard I have lying around, as well as my mouse. For whatever reason the k70 doesnt work with the scripts. The keyboard is detected in the monitor app and I made sure the ID's were correct, swapped usb ports, etc. Anyone have any solutions or is there the possibility that AHI just doesnt work with all models of keyboards?
Swagcheck
Posts: 10
Joined: 13 Jan 2020, 08:51

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

24 Jan 2020, 09:22

This works for me until after I restart my computer a second time (after installation). That's when I can't enter my Windows (7) password because my keyboard is completely unresponsive and the only to fix it is by doing a system restore. I tried installing again and the same thing happened, very frustrating. What could have gone wrong?

Edit: It seems the game I play (UGG GunZ) is causing this. With the Interception driver installed the game crashes within 30 seconds without even using AHI. Then I have to uninstall the driver or else my keyboard won't work the next time I reboot, again forcing me to system restore. This doesn't happen if I don't open the game. Any ideas?
Last edited by Swagcheck on 24 Jan 2020, 13:12, edited 1 time in total.
Typical-User
Posts: 8
Joined: 15 Jun 2019, 06:38

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

24 Jan 2020, 11:46

I managed to find what caused the trouble to the non working script. A ";" before func was the issue :D
Script is working now, but have a problem in functionality. The problem caused by the increased sleep timer i use (260000).
And when i need to restart script, it needs to finish the loop first.
In order to keep code more understandable to me, and functionality as used to be, i modified a bit the code to suit my needs.
I might ended having 10 scripts to run, but i cannot have it all.
In order to free the keys from keyboard i write, i used the virtual keys scan codes from F13 to F18.
So, code ended to be.

Code: Select all

 #NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance force
#Persistent
#include d:\Scripting\AutoHotInterception\Lib\AutoHotInterception.ahk
AHI := new AutoHotInterception()
keyboardId := AHI.GetKeyboardId(0x0E8F, 0x0041)

; The "true" parameter in SubscribeKey tells AHI to BLOCK (Hide from the OS) this key.
AHI.SubscribeKey(keyboardId, GetKeySC("NumpadHome"), true, Func("KeyEvent"))
return

^!o::ExitApp

KeyEvent(state){
	global AHI, keyboardId
    ; state will be 1 on key press, 0 on key release
	if (!state)
		return    ; Ignore key release events
	AHI.SendKeyEvent(keyboardId, GetKeySC("vk0x7C"), 1)   ;Sends F13 Key
}
return
Thnak you very much for your help, and your time. 8-)
Swagcheck
Posts: 10
Joined: 13 Jan 2020, 08:51

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

24 Jan 2020, 23:55

Swagcheck wrote:
24 Jan 2020, 09:22
This works for me until after I restart my computer a second time (after installation). That's when I can't enter my Windows (7) password because my keyboard is completely unresponsive and the only to fix it is by doing a system restore. I tried installing again and the same thing happened, very frustrating. What could have gone wrong?

Edit: It seems the game I play (UGG GunZ) is causing this. With the Interception driver installed the game crashes within 30 seconds without even using AHI. Then I have to uninstall the driver or else my keyboard won't work the next time I reboot, again forcing me to system restore. This doesn't happen if I don't open the game. Any ideas?
Forgot to mention that I get this error when the game crashes, or sometimes no error at all:

"The instruction at 0x00525f5d referenced memory at 0x9f140a33. The memory could not be read."
iCeCoCaCoLa64
Posts: 2
Joined: 27 Jan 2020, 23:44

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

28 Jan 2020, 01:38

I'm using a standalone USB numpad for macros, and I never had a problem with it while using Intercept. But with AHI, I have a weird problem where the script will become less responsive/reliable over time. When I first run the script, it's smooth as butter— I can spam keys on the numpad and all the macros will work with no problem. But say about an hour later, hitting a key on the numpad has a good chance of not activating the macro, and instead just having it do its normal function. The only way to fix it is to manually reload the script. Not even creating a timer that reloads the script every 60 seconds will work, it has to be a manual reload. I haven't seen anyone else in this thread with this problem, and I've never had this problem with normal AHK scripts, so I'm wondering if you have any idea why this is happening.

Here's the script I'm using. If it matters, it's an .ahk file that I'm running as admin (compiling to an .exe prevents the script from finding interception.dll for some reason). I saw your post on the previous page and compiled the script to an .exe, but my problem is still occurring.
Spoiler
CryptoGuppy
Posts: 2
Joined: 16 Feb 2020, 07:44

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

16 Feb 2020, 07:59

iCeCoCaCoLa64 wrote:
28 Jan 2020, 01:38
I'm using a standalone USB numpad for macros, and I never had a problem with it while using Intercept. But with AHI, I have a weird problem where the script will become less responsive/reliable over time. When I first run the script, it's smooth as butter— I can spam keys on the numpad and all the macros will work with no problem. But say about an hour later, hitting a key on the numpad has a good chance of not activating the macro, and instead just having it do its normal function. The only way to fix it is to manually reload the script. Not even creating a timer that reloads the script every 60 seconds will work, it has to be a manual reload. I haven't seen anyone else in this thread with this problem, and I've never had this problem with normal AHK scripts, so I'm wondering if you have any idea why this is happening.

Here's the script I'm using. If it matters, it's an .ahk file that I'm running as admin (compiling to an .exe prevents the script from finding interception.dll for some reason). I saw your post on the previous page and compiled the script to an .exe, but my problem is still occurring.
Spoiler
I don't know if I am committing a forum sin with this (new here) but I am doing something similar with an external numpad using HidMacros (http www.hidmacros.eu) and AHK. Maybe this could work for you too?
rommmcek
Posts: 1009
Joined: 15 Aug 2014, 15:18

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

17 Feb 2020, 11:32

@iCeCoCaCoLa64: Try to use a second Ahk script with timer, to close your script and re-run it again periodically.
M_L
Posts: 13
Joined: 21 Mar 2016, 06:54

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

16 Mar 2020, 13:09

Can you use an external mouse together with AHI?
If so, how?
iCeCoCaCoLa64
Posts: 2
Joined: 27 Jan 2020, 23:44

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

24 Mar 2020, 13:48

CryptoGuppy wrote:
16 Feb 2020, 07:59
I don't know if I am committing a forum sin with this (new here) but I am doing something similar with an external numpad using HidMacros (http www.hidmacros.eu) and AHK. Maybe this could work for you too?
I've used a few other things such as HIDMacros and Intercept, but no matter what I'm using, I always end up wrapping through AHK anyway. So I'd much rather just use AHK, and AHI works very well when it does work. So rather than go back to using something else, I'd rather have some help from the creator to get it working consistently.
rommmcek wrote:
17 Feb 2020, 11:32
@iCeCoCaCoLa64: Try to use a second Ahk script with timer, to close your script and re-run it again periodically.
I'm looking for a fix, not a workaround.
phasermaniac
Posts: 74
Joined: 09 Apr 2017, 14:05

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

10 Apr 2020, 07:06

Hi! I got this code for crt lightguns working with version 3.0.
I updated to last version and I have a little problem with the 0,0 coordinates:
Before, I could detect when I was aiming offscreen this way:

Code: Select all

if (OffscreenReload && this.x=0 && this.y=0)
But after updating, I can't detect when I'm aiming offscreen.
Also, If the very first shoot is offscreen, I get an error with AHI.SendMouseButtonEventAbsolute.
I can resolve this error setting this.x:=0, this.y:=0 inside Classgun, but seems evident it has something to do with the offscreen detection problem.
Any advise? Thanks!

This code is for launching an screen flash with another program (with A and K keys), that crt guns need to see before the gun trigger pressure.

Code: Select all

#SingleInstance force
#Persistent
;#NoTrayIcon
#NoEnv
;#Warn, All, OutputDebug
#MaxHotkeysPerInterval 255
#MaxThreads 255
SetKeyDelay -1
;SetBatchLines -1
SetWorkingDir %A_ScriptDir%

Process, Priority,,High
#include <AutoHotInterception>

global shotdelay := 40
global shotlength := 60
global OffscreenReload := 1
global BlockTracking := 0
global HideCrosshair := 0
;global mx, my
global Xrange := 1
global Yrange := 1
global Xoffset := 0
global Yoffset := 0

AHIWrapper := new AutoHotInterception()
global AHI := AHIWrapper.GetInstance()

devices := AHIWrapper.GetDeviceList()
if (!devices.Length()){
	msgbox Device List Check faileda
	ExitApp
}


id1 := 11
;id2 := 12

gun1 := new Gun(id1, "a")
;gun2 := new Gun(id2, "k")

return
F12::
	ExitApp

; ==========================================================================
Class Gun {
	__New(id, flashkey ){
		this.id := id
		this.flashkey := flashkey
		AHI.SubscribeMouseButton(this.id, 0, true, this.ButtonEvent.Bind(this))
		if (HideCrosshair){
			this.SetMoveState(HideCrosshair)
		}
		else{
			this.SetMoveState(BlockTracking)
		}
	}
	
	ButtonEvent(state){
		if (state){
			this.SimulateShot()		
		}
		if (!state && shotlength="auto"){
			this.SetButtonState(0, 0 , this.x, this.y)
		}
	}

	MouseEvent(x, y){
		this.x := x, this.y := y
	}
	
	SimulateShot(){
		Send % this.flashkey
			fn := this.ButtonDown.Bind(this, button)
			SetTimer, % fn, % "-" shotdelay
	}
	
	buttonDown(button){
		if (OffscreenReload && this.x=0 && this.y=0){
			x:=0
			y:=0
			button:=1
		}
		else{
			x:=this.x*Xrange+Xoffset
			y:=this.y*Yrange+Yoffset
			button:=0	
		
		}
		this.SetButtonState(button, 1, x, y)
		fn := this.ButtonUp.Bind(this, button, x, y)
		SetTimer, % fn, % "-" shotlength
	}
	
	buttonUp(button, x, y){
		this.SetButtonState(button, 0 , x, y)
		if (HideCrosshair){
			x:=0
			y:=0
			this.SetButtonState(button, 0 , x, y)
		}	
	}

	SetButtonState(button, state, x, y){
		AHI.SendMouseButtonEventAbsolute(this.id, button, state, x, y)
		;AHI.SendMouseButtonEvent(this.id, button, state)
	}

	SetMoveState(blocked){
		AHI.SubscribeMouseMoveAbsolute(this.id, blocked, this.MouseEvent.Bind(this))
	}
}
I was also trying to do the flashing with ahk, so I don't need the flasher program, to simplify it and share, but I don't find a proper way to do it:
I found an "always on top fullscreen white gui solution" that seems to work but It won't with opengl fullscreen applications.
I found another way Increasing gamma or brightness but they seems to have a max level that is not enought bright for my case.
Do you know some way to do it?

Hope for some help, I spend a few hours in these thinks and I can't resolve.
Thanks!
User avatar
evilC
Posts: 4776
Joined: 27 Feb 2014, 12:30

Re: AutoHotInterception (AHI): Multi-Keyboard / Multi-Mouse support for AHK. Per-device blocking!

10 Apr 2020, 14:39

@phasermaniac You appear to be correct
https://github.com/evilC/AutoHotInterception/issues/62

I have released AHI 0.5.1 with a fix

Code: Select all

### Added
- AHI now supports scripts being compiled.
You will still need the DLLs from the Lib folder, but not the AHK scripts
### Fixed
- Fix issue 62 - x=0/y=0 never reported for Absolute mode mouse move

Return to “Scripts and Functions”

Who is online

Users browsing this forum: Avastgard, elvo11, gwarble and 26 guests